home *** CD-ROM | disk | FTP | other *** search
/ Super CD / Super CD.iso / geomitri / rcd / footings.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1989-06-10  |  19.7 KB  |  520 lines
  1. 2       ' This programme is used to design  WALL &COLUMNS FOOTINGS
  2. 3       ' This programme uses Advanced Basic Language  (IBM - BASICA )
  3. 4       ' This programme is saved under the name    [ FOOTINGS ]
  4. 5       ' Prepared by   AMJAD J. SHAIR    23/1/1986 - 25/1/1986
  5. 6  SCREEN 0,1 :WIDTH 40 :COLOR 15,1,0 :CLS :LOCATE 5
  6. 7  PRINT "   REINFORCED CONCRETE FOOTINGS DESIGN                                                    Prepared by :                                                               AMJAD JAMIL EL-SHA'IR "
  7. 8  LOCATE 25,5 :PRINT "PRESS SPACE BAR TO CONTINUE ";
  8. 9  Y$=INKEY$ :IF Y$<>" " THEN 9
  9. 10  '---------------------------------------------------------- Enter Basic Data
  10. 20  SCREEN 0,1 :WIDTH 80 :COLOR 15,1,0
  11. 30  CLEAR
  12. 40  OPEN "DATA1" FOR INPUT AS #1
  13. 50  IF EOF(1) THEN CLOSE :GOTO 100
  14. 60  INPUT #1,PRJ$,BLD$,DSR$,FC,FY,FYS,QA
  15. 70  GOTO 50
  16. 100  '------------------------------------------------------ Footings Types Menu
  17. 110  CLS :LOCATE 2,8
  18. 120  PRINT "  ****       REINFORCED CONCRETE FOOTINGS       ****"
  19. 130  PRINT
  20. 140  PRINT "   Concrete Crushing Strength  f'c ="FC" kg/cm2  "
  21. 150  PRINT "   Reinf' Steel Yield Stress   fy  ="FY" kg/cm2  "
  22. 160  PRINT
  23. 170  PRINT "   Allowable Soil Bearing Capacity           q (all)  ="QA" kg/cm2"
  24. 180  PRINT :PRINT
  25. 190  PRINT "           ****      FOOTINGS TYPES MENU    ****"
  26. 200  PRINT
  27. 210  PRINT "             [ W ]  -  CONCRETE WALL FOOTING          "
  28. 220  PRINT
  29. 230  PRINT "             [ C ]  -  SINGLE COLUMN FOOTING          "
  30. 240  PRINT
  31. 250  PRINT "             [ R ]  -  RETURN TO  RCDESIGN  MAIN MENU "
  32. 260  PRINT :PRINT
  33. 270  PRINT "      ENTER THE LETTERS IN BRACKETS FOR THE FOOTING TYPE :";
  34. 280  FT$=INKEY$ :IF FT$="" THEN 280
  35. 290  IF FT$="W" OR FT$="w" THEN PRINT " WALL FOOTING " :GOTO 400
  36. 300  IF FT$="C" OR FT$="c" THEN PRINT " COLUMN FOOTING " :GOTO 2500
  37. 310  IF FT$="R" OR FT$="r" THEN PRINT " RCDESIGN MAIN MENU " :CHAIN "RCDESIGN",2500
  38. 320  GOTO 270
  39. 400  '*********************   CONCRETE WALL FOOTING   **************************
  40. 410  '---------------------------------------- Calculation of Footing Dimentions
  41. 415  CLS :LOCATE 2,10
  42. 420  PRINT "***************   CONCRETE WALL FOOTING   ***************"
  43. 425  PRINT :LOCATE ,7
  44. 430  INPUT " ENTER THE MINIMUM FOOTING THICKNESS TO BE USED (cm) ",HMIN
  45. 440  INPUT " ENTER THE LOAD MULTIPL. FACTOR TO ALLOW FOR WEIGHT OF FOOTING & FILL ",LFCT
  46. 450  IF LFCT<1.1 THEN LFCT = 1.1
  47. 480  CLS :LOCATE 2,10
  48. 482  PRINT "***************   CONCRETE WALL FOOTING   ***************"
  49. 484  PRINT :LOCATE ,10
  50. 486  INPUT "   ENTER  WALL FOOTING NUMBER    SECTION ",NMB
  51. 488  GOSUB 6200
  52. 490  PRINT
  53. 492  INPUT "   ENTER  WALL ULTIMATE UNF. LOAD INTENSITY     Wu  (ton/m) ",WU
  54. 494  IF WU>0 GOTO 530
  55. 496  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  56. 498  INPUT "  ****  INVALID ZERO UNIFORM LOAD    RE-ENTER   Wu   ****  ",WU
  57. 500  COLOR ,1:PRINT
  58. 510  IF WU<=0 THEN GOSUB 6100 ELSE GOTO 530
  59. 520  GOTO 2210
  60. 530  PRINT
  61. 540  INPUT "   ENTER  WIDTH OF CONCRETE WALL                Bw  (cm)    ",BW
  62. 550  IF BW>0 GOTO 610
  63. 560  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  64. 570  INPUT "  ****  INVALID ZERO WIDTH OF WALL   RE-ENTER   Bw   ****  ",BW
  65. 580  COLOR ,1:PRINT
  66. 590  IF BW<=0 THEN GOSUB 6100 ELSE GOTO 610
  67. 600  GOTO 2210
  68. 610  PRINT
  69. 620  WW=WU/1.5                 'Working Load (t/m2)= Ult.Load / Ult.Load Factor
  70. 630  B=100*WW*LFCT/(QA*10)            'Width of Footing  (cm)
  71. 640  QU=WU*10/B                      'Ult. Pressure on Soil  (kg/cm2)
  72. 650  D=(B-BW)/(2+0.85*1.06*SQR(FC)/QU)     'Depth of Footing  (cm)
  73. 660  B1=CINT(B)
  74. 670  H1=CINT(D)+5
  75. 680  PRINT "   Min. Required Width  of Footing   B  ="B1" cm"
  76. 690  PRINT
  77. 700  PRINT "   Min. Required Height of Footing   H  ="H1" cm"
  78. 710  PRINT
  79. 720  INPUT "   ENTER the Preferable  Width  of Footing  (cm)   B = ",B
  80. 730  IF B>=(0.975*B1) GOTO 790
  81. 740  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  82. 750  INPUT "  ****  INADEQUATE WIDTH  OF FOOTING * RE-ENTER   B  ****  ",B
  83. 760  COLOR ,1:PRINT
  84. 770  IF B<(0.975*B1) THEN GOSUB 6100 ELSE GOTO 790
  85. 780  GOTO 2210
  86. 790  INPUT "   ENTER the Preferable  Height of Footing  (cm)   H = ",H
  87. 800  IF H>=H1 GOTO 860
  88. 810  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  89. 820  INPUT "  ****  INADEQUATE HEIGHT OF FOOTING * RE-ENTER   H  ****  ",H
  90. 830  COLOR ,1:PRINT
  91. 840  IF H<H1 THEN GOSUB 6100 ELSE GOTO 860
  92. 850  GOTO 2210
  93. 860  IF H<HMIN THEN H=HMIN
  94. 865  Q=WW*LFCT*10/B                   'Working  Pressure on Soil (kg/cm2)
  95. 870  IF Q<=(1.025*QA) GOTO 910
  96. 880  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  97. 890  INPUT "  ****  INADEQUATE WIDTH  OF FOOTING * RE-ENTER   B  ****  ",B
  98. 900  COLOR ,1:PRINT :GOTO 640
  99. 910  QU=WU*10/B        '(kg/cm2)
  100. 920  D=H-5
  101. 930  VSC=0.53*SQR(FC)    '(kg/cm2)
  102. 940  VF=QU*(B-BW-2*D)/2
  103. 950  VS=VF/(0.85*D)
  104. 960  IF VS>VSC GOTO 810
  105. 970  Q=(CINT(Q*100))/100
  106. 980  QU=(CINT(QU*100))/100
  107. 990  VSC=(CINT(VSC*100))/100
  108. 1100  '--------------------------- Display Footing Dimensios & Checking Stresses
  109. 1110  GOSUB 6200
  110. 1120  PRINT "   FOOTING DIMENSIONS  :    Width   B = "B" cm     *   HEIGHT   H ="H" cm"
  111. 1130  PRINT
  112. 1140  PRINT "   Check Pressure on Soil   : "
  113. 1150  PRINT "  ----------------------------"
  114. 1160  PRINT "         q = Wu*"LFCT"*10/(1.5 *B) ="Q" kg/cm2  < q (all)="QA" kg/cm2"
  115. 1170  PRINT
  116. 1180  PRINT "   Ult. Pressure on Footing : "
  117. 1190  PRINT "  ----------------------------"
  118. 1200  PRINT "         q (ult)  =  Wu *10/B   ="QU" kg/cm2 "
  119. 1210  PRINT
  120. 1220  PRINT "   Check for Shear Stress   : "
  121. 1230  PRINT "  ----------------------------"
  122. 1240  PRINT "        All.Shear Stress for Concrete   =.53*SQR(f'c) ="VSC"kg/cm2"
  123. 1250  PRINT "        vu = q(ult)*(B-Bw-2D)/(2*.85*D) ="VS" kg/cm2  < vc ="VSC
  124. 1260  PRINT :PRINT
  125. 1270  PRINT "         Press  SPACE BAR  to Display  Reinforcement  ..... ";
  126. 1280  IF INKEY$<>" " THEN 1280
  127. 1300  '----------------------------------------- Calculation & Display of Reinf'
  128. 1310  GOSUB 6200
  129. 1320  PRINT "   FOOTING DIMENSIONS  :    Width   B = "B" cm     *   HEIGHT   H ="H" cm"
  130. 1330  PRINT
  131. 1340  MU=QU*((B-BW)/2)^2*100/2
  132. 1350  GOSUB 6400
  133. 1360  AS1=(CINT(AS*100))/100 :MU1=(CINT(MU/1000))/100
  134. 1370  AS(MIN)=0.00185*H*100
  135. 1380  PRINT "   REINFORCEMENT  :"
  136. 1390  PRINT "      Moment at Face of Wall  Mu ="MU1" t.m "
  137. 1400  IF AS1>=AS(MIN) GOTO 1430
  138. 1410  PRINT "      Required Area of Steel  As ="AS1" cm2  <  As (min.)="AS(MIN)" cm2)
  139. 1420  AS=AS(MIN) :GOTO 1440
  140. 1430  PRINT "      Required Area of Steel  As ="AS1" cm2  >  As (min.)="AS(MIN)" cm2)
  141. 1440  PRINT
  142. 1450  PRINT "    Choices of Reinf' :"
  143. 1460  FOR S=10 TO 20 STEP 5
  144. 1470  DIA =2+2*INT(10*SQR((4*AS*S)/(100*3.14159))/2.001)
  145. 1480  AP=(3.14159*(DIA/10)^2/4)*100/S
  146. 1490  PRINT "   *  "CHR$(237);DIA " mm  @"S" cm  Spacing  *  As (provided) ="AP" cm2"
  147. 1500  NEXT
  148. 1510  PRINT
  149. 1520  INPUT "   ENTER  any Bar  SPACING  to be used     ( 10 cm - 25 cm ) ",S
  150. 1530  IF S<10 OR S>25 THEN BEEP :GOTO 1520
  151. 1540  DIA =2+2*INT(10*SQR((4*AS*S)/(100*3.14159))/2.001)
  152. 1550  AP=(CINT((3.14159*(DIA/10)^2/4)*100/S*100))/100
  153. 1560  PRINT :LOCATE ,4 :COLOR 0,4
  154. 1570  PRINT " USE  [  "CHR$(237);DIA " mm @"S" cm  Spacing   As (provided) ="AP" cm2 "
  155. 1600  '---------------------------------------------------- PRINT DATA & RESULTS
  156. 1610  COLOR 15,1 :PRINT
  157. 1615  PRINT "     ***  DO YOU WHANT THIS WALL FOOTING DESIGN TO BE PRINTED  (Y/N) ?  ***";
  158. 1620  Y$=INKEY$ :IF Y$="" THEN 1620
  159. 1625  IF Y$="Y" OR Y$="y" THEN PRINT " YES" :GOTO 1640
  160. 1630  IF Y$="N" OR Y$="n" THEN PRINT " NO " :GOTO 2210
  161. 1635  GOTO 1615
  162. 1640  H$=STRING$(79,61)
  163. 1650  IF FY<=3000 THEN BRDA$=CHR$(239)+CHR$(8)+CHR$(47) ELSE BRDA$=CHR$(111)+CHR$(8)+CHR$(84)
  164. 1652  LPRINT
  165. 1655  LPRINT CHR$(14)"Arabian Consulting Engineering Services"
  166. 1660  LPRINT "P. O. Box  146                                           Riyadh - Saudi Arabia"
  167. 1665  LPRINT H$
  168. 1670  LPRINT CHR$(14)" PROJECT: "PRJ$
  169. 1675  LPRINT
  170. 1680  LPRINT "  BUILDING    : "BLD$ TAB(58)"PAGE No.:"
  171. 1685  LPRINT "  DESIGNED BY : "DSR$ TAB(31)"/ CHECKED BY : "TAB(58)"DATE    : "DATE$
  172. 1690  LPRINT :LPRINT H$
  173. 1695  LPRINT "  RCDESIGN PROGRAM PREPARED BY : Amjad J.El-Sha'ir, P.O.Box 926447 Amman-Jordan"
  174. 1700  LPRINT "  THIS COPY TO BE USED ONLY BY : Arabian Consulting Engineering Services  K.S.A"
  175. 1705  LPRINT H$
  176. 1710  LPRINT CHR$(14) " WALL FOOTING "TAB(27) "SECTION"NMB"-"NMB
  177. 1720  LPRINT H$ :LPRINT
  178. 1730  LPRINT CHR$(27)"G";
  179. 1740  LPRINT "  ** SOIL CONDITIONS **  "
  180. 1750  LPRINT CHR$(27)"H";"  ---------------------  "
  181. 1760  LPRINT "   - Allowable Soil Bearing Capacity   q (all.) ="QA" kg/cm2  "
  182. 1770  LPRINT CHR$(27)"G"
  183. 1780  LPRINT "  ** CONCRETE & STEEL PROPERTIES **  "
  184. 1790  LPRINT CHR$(27)"H";"  ---------------------------------  "
  185. 1800  LPRINT "   - Concrete Crushing Strength  f'c ="FC" kg/cm2  "
  186. 1810  LPRINT "   - Reinf' Steel Yield Stress   fy  ="FY" kg/cm2  "
  187. 1820  LPRINT H$ :LPRINT
  188. 1830  LPRINT CHR$(27)"G";
  189. 1840  LPRINT "  ** WALL WIDTH & LOADING **  "
  190. 1850  LPRINT CHR$(27)"H";"  --------------------------  "
  191. 1860  LPRINT "   - Width of Wall               Bw ="BW" cm"
  192. 1870  LPRINT "   - Ultimate Unf. Load on Wall  Wu ="WU" ton/meter~ "
  193. 1880  LPRINT CHR$(27)"G"
  194. 1890  LPRINT "  ** FOOTING  DIMENSIONS **  "
  195. 1900  LPRINT CHR$(27)"H";"  -------------------------  "
  196. 1910  LPRINT "   - Plain  Concrete  :   Width  B'="B+20" cm      Height  H'= 10 cm "
  197. 1920  LPRINT "   - Reinf' Concrete  :   Width  B ="B" cm      Height  H ="H" cm"
  198. 1930  LPRINT :LPRINT H$
  199. 1940  LPRINT "  Min reinf' Steel Area  As(min)= .002 X H X 100 ="AS(MIN)"   cm2 /m~ of wall"
  200. 1950  LPRINT "  Max. Ultimate Shear Stress in Concrete     vuc ="VSC" kg/cm2"
  201. 1960  LPRINT H$
  202. 1970  LPRINT :LPRINT
  203. 1980  LPRINT "  **  Check Pressure on Soil  ** "
  204. 1990  LPRINT "  ------------------------------ "
  205. 2000  LPRINT "     q = Wu x"LFCT"x 10/ (1.50 x B) ="Q" kg/cm2  < q (all)"
  206. 2010  LPRINT
  207. 2020  LPRINT "  **  Ult. Pressure on Footing  **"
  208. 2030  LPRINT "  --------------------------------"
  209. 2040  LPRINT "     q (ult)  =  Wu x 10/B   ="QU" kg/cm2 "
  210. 2050  LPRINT
  211. 2060  LPRINT "  **  Check for Shear Stress  ** "
  212. 2070  LPRINT "  ------------------------------ "
  213. 2080  LPRINT "     vu = q(ult) x (B-Bw-2D)/(2 x.85 x D)  ="VS" kg/cm2  < vc
  214. 2090  LPRINT :LPRINT
  215. 2100  LPRINT "  **  FOOTING REINFORCEMENT  **  "
  216. 2110  LPRINT "  -----------------------------  "
  217. 2120  LPRINT "      Moment at Face of Wall  Mu ="MU1" t.m "
  218. 2130  IF AS1>=AS(MIN) GOTO 2160
  219. 2140  LPRINT "      Required Area of Steel  As ="AS1" cm2  <  As (min.)"
  220. 2150  GOTO 2170
  221. 2160  LPRINT "      Required Area of Steel  As ="AS1" cm2  >  As (min.)"
  222. 2170  LPRINT CHR$(27)"G"
  223. 2180  LPRINT "  USE  [  "BRDA$;DIA " mm @"S" cm  Spacing  ]" TAB(54)"As (prov.) ="AP" cm2 "
  224. 2200  LPRINT CHR$(27) "H":LPRINT CHR$(12)
  225. 2210  PRINT
  226. 2220  PRINT "     ***  DO YOU HAVE OTHER WALL FOOTINGS TO DESIGN            (Y/N) ?  ***";
  227. 2230  Y$=INKEY$ :IF Y$="" THEN 2230
  228. 2240  IF Y$="Y" OR Y$="y" THEN PRINT " YES" :GOTO 480
  229. 2250  IF Y$="N" OR Y$="n" THEN PRINT " NO " :GOTO 110
  230. 2260  GOTO 2220
  231. 2500  '*******************   SINGLE COLUMN FOOTING   **************************
  232. 2510  '--------------------------------------- Calculation of Footing Dimentions
  233. 2515  CLS :LOCATE 2,10
  234. 2520  PRINT "**************   SINGLE COLUMN FOOTING   ******************"
  235. 2525  PRINT :LOCATE ,7
  236. 2528  INPUT " ENTER THE MINIMUM FOOTING THICKNESS TO BE USED (cm) ",HMIN
  237. 2530  INPUT " ENTER THE LOAD MULTIPL. FACTOR TO ALLOW FOR WEIGHT OF FOOTING & FILL ",LFCT
  238. 2540  IF LFCT<1.1 THEN LFCT = 1.1
  239. 2580  CLS :LOCATE 2,10
  240. 2582  PRINT "**************   SINGLE COLUMN FOOTING   ******************"
  241. 2584  PRINT :LOCATE ,15
  242. 2586  INPUT "   ENTER  FOOTING  NUMBER      F ",NMB
  243. 2588  GOSUB 6300
  244. 2590  PRINT
  245. 2592  INPUT "   ENTER  COLUMN  ULTIMATE  LOAD               Pu  (ton)   ",PU
  246. 2594  IF PU>0 GOTO 2630
  247. 2596  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  248. 2598  INPUT "  ****  INVALID ZERO COLUMNM LOAD    RE-ENTER   Pu   ****  ",PU
  249. 2600  COLOR ,1:PRINT
  250. 2610  IF PU>0 GOTO 2630 ELSE GOSUB 6100
  251. 2620  GOTO 4900
  252. 2630  PRINT
  253. 2640  INPUT "   ENTER  LONGER DIMENSION OF COLUMN SECTION    Tc  (cm)   ",TC
  254. 2650  IF TC>0 GOTO 2710
  255. 2660  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  256. 2670  INPUT "  ****  INVALID ZERO LENGTH OF COL.  RE-ENTER   Tc   ****  ",TC
  257. 2680  COLOR ,1:PRINT
  258. 2690  IF TC>0 GOTO 2710 ELSE GOSUB 6100
  259. 2700  GOTO 4900
  260. 2710  PRINT
  261. 2720  INPUT "   ENTER  SHORT  DIMENSION OF COLUMN SECTION    Bc  (cm)   ",BC
  262. 2730  IF BC >0 GOTO 2790
  263. 2740  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  264. 2750  INPUT "  ****  INVALID ZERO WIDTH OF COL.   RE-ENTER   Bc   ****  ",BC
  265. 2760  COLOR ,1:PRINT
  266. 2770  IF BC>0 GOTO 2790 ELSE GOSUB 6100
  267. 2780  GOTO 4900
  268. 2790  PRINT
  269. 2800  PW=PU/1.5
  270. 2810  A=LFCT*PW*1000/QA                          'Required Area of Footing
  271. 2820  C=(-(TC+BC)+SQR((TC+BC)^2-4*(TC*BC-A)))/4 'Required Cantilever from face
  272. 2830  L=TC+2*C
  273. 2840  B=BC+2*C
  274. 2850  QU=PU*1000/(L*B)
  275. 2860  D=C/(1+0.53*0.85*SQR(FC)/QU) :D=(INT(D/5.001))*5+5
  276. 2870  GOSUB 6500
  277. 2880  H1=D+5
  278. 2890  IF H1<HMIN THEN H1=HMIN
  279. 2900  L1=CINT(L) :B1=CINT(B)
  280. 2910  IF L1=B1 GOTO 3000
  281. 2920  L=SQR(A)
  282. 2930  C=(L-BC)/2
  283. 2940  QU=PU*1000/L^2
  284. 2950  D=C/(1+0.83*0.85*SQR(FC)/QU) :D=(INT(D/5.001))*5+5
  285. 2960  GOSUB 6500
  286. 2970  H2=D+5
  287. 2980  IF H2<HMIN THEN H2=HMIN
  288. 2990  L2=CINT(L)
  289. 3000  PRINT "  Min. Req. Dimensions of Footing :"
  290. 3010  PRINT "  - Most Economical Footing    L X B X H ="L1" X"B1" X"H1" cm"
  291. 3020  IF L1=B1 GOTO 3040
  292. 3030  PRINT "  - Using  a Square Footing    L X B X H ="L2" X"L2" X"H2" cm"
  293. 3040  PRINT
  294. 3050  INPUT "   ENTER the Preferable  Length of Footing  (cm)   L = ",L
  295. 3060  IF L>0 GOTO 3120
  296. 3070  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  297. 3080  INPUT "  ****  INVALID  ZERO LENGTH         * RE-ENTER   L  ****  ",L
  298. 3090  COLOR ,1:PRINT
  299. 3100  IF L>0 GOTO 3120 ELSE GOSUB 6100
  300. 3110  GOTO 4900
  301. 3120  INPUT "   ENTER the Preferable  Width  of Footing  (cm)   B = ",B
  302. 3130  IF B>0 GOTO 3190
  303. 3140  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  304. 3150  INPUT "  ****  INVALID  ZERO WIDTH          * RE-ENTER   B  ****  ",B
  305. 3160  COLOR ,1:PRINT
  306. 3170  IF B>0 GOTO 3190 ELSE GOSUB 6100
  307. 3180  GOTO 4900
  308. 3190  Q=LFCT*PW*1000/(L*B) :Q=(CINT(Q*100))/100
  309. 3200  IF Q<=(1.025*QA) GOTO 3260
  310. 3210  PRINT :LOCATE ,10 :COLOR ,4 :BEEP
  311. 3220  PRINT " ** FOR "L " X"B " cm FOOTING   q="Q  " kg/cm2 > q(all) ** "
  312. 3230  LOCATE ,10
  313. 3240  PRINT " ** INADEQUATE DIMENSIONS OF FOOTING   * RE-ENTER  L,B  ** "
  314. 3250  COLOR ,1 :PRINT  :GOTO 3000
  315. 3260  QU=PU*1000/(L*B)
  316. 3270  C1=(L-TC)/2
  317. 3280  C2=(B-BC)/2
  318. 3290  IF C1>C2 THEN C=C1 ELSE C=C2
  319. 3300  D=C/(1+0.53*0.85*SQR(FC)/QU) :D=(INT(D/5.001))*5+5
  320. 3310  GOSUB 6500
  321. 3320  H=D+5
  322. 3330  IF H<HMIN THEN H=HMIN
  323. 3340  VS=QU*(C-D)/(0.85*D)
  324. 3350  Q=(CINT(Q*100))/100
  325. 3360  QU=(CINT(QU*100))/100
  326. 3370  VSC=(CINT(0.53*SQR(FC)*100))/100
  327. 3380  VS=(CINT(VS*100))/100
  328. 3500  '--------------------------- Display Footing Dimensios & Checking Stresses
  329. 3510  GOSUB 6300
  330. 3520  PRINT " FOOTING DIM.:  Length  L ="L" cm  * WIDTH  B ="B" cm  * HEIGHT  H ="H" cm"
  331. 3530  PRINT
  332. 3540  PRINT "   Check Pressure on Soil   : "
  333. 3550  PRINT "  ----------------------------"
  334. 3560  PRINT "     q ="LFCT"*Pu*1000/(1.5 *B*L) ="Q" kg/cm2  < q (all)="QA" kg/cm2"
  335. 3570  PRINT
  336. 3580  PRINT "   Ult. Pressure on Footing : "
  337. 3590  PRINT "  ----------------------------"
  338. 3600  PRINT "     q (ult)  =   Pu *1000/B    ="QU" kg/cm2 "
  339. 3610  PRINT
  340. 3620  PRINT "   Check for Shear Stress   : "
  341. 3630  PRINT "  ----------------------------"
  342. 3640  PRINT "     All.Shear Stress for Concrete  vc  =.53*SQR(f'c) ="VSC"kg/cm2"
  343. 3650  PRINT "     Shear Stress at (d) from Col. face ="VS" kg/cm2  < vc ="VSC
  344. 3660  PRINT
  345. 3670  PRINT "   Check for Punch Stress   : "
  346. 3680  PRINT "  ----------------------------"
  347. 3690  PRINT "     All.Punch Stress for Concrete  vpc = SQR(f'c) ="VPC"kg/cm2"
  348. 3700  PRINT "     Punching Shear Stress              ="VPS" kg/cm2  < vpc"
  349. 3710  PRINT :PRINT
  350. 3720  PRINT "         Press  SPACE BAR  to Display  Reinforcement  ..... ";
  351. 3730  IF INKEY$<>" " THEN 3730
  352. 3800  '----------------------------------------- Calculation & Display of Reinf'
  353. 3810  GOSUB 6300
  354. 3820  PRINT " FOOTING DIM.:  Length  L ="L" cm  * WIDTH  B ="B" cm  * HEIGHT  H ="H" cm"
  355. 3830  PRINT
  356. 3840  MU=QU*C^2*100/2
  357. 3850  GOSUB 6400
  358. 3860  AS1=(CINT(AS*100))/100 :PS1=(CINT(PS*1000))/1000 :MU1=(CINT(MU/1000))/100
  359. 3870  AS(MIN)=0.002*H*100
  360. 3880  PRINT "   REINFORCEMENT  :"
  361. 3890  PRINT "      Moment at Face of Wall  Mu ="MU1" t.m /one meter strip"
  362. 3900  IF AS1>=AS(MIN) GOTO 3930
  363. 3910  PRINT "      Required Area of Steel  As ="AS1" cm2/m  <  As (min.)="AS(MIN)" cm2)
  364. 3920  AS=AS(MIN) :GOTO 3940
  365. 3930  PRINT "      Required Area of Steel  As ="AS1" cm2/m  >  As (min.)="AS(MIN)" cm2)
  366. 3940  PRINT
  367. 3950  PRINT "    Choices of Reinf' :"
  368. 3960  FOR S1=10 TO 20 STEP 5
  369. 3970  DIA =2+2*INT(10*SQR((4*AS*S1)/(100*3.14159))/2.001)
  370. 3975  S=INT(3.14159*DIA^2*100/(4*AS))/100
  371. 3980  AP=(3.14159*(DIA/10)^2/4)*100/S
  372. 3990  PRINT "   *  "CHR$(237);DIA " mm  @"S" cm  Spacing  *  As (provided) ="AP" cm2"
  373. 4000  NEXT
  374. 4010  PRINT
  375. 4020  INPUT "   ENTER    BAR DIAMETER    to be used     ( 10 mm - 25 mm ) ",DIA
  376. 4025  IF DIA <10 OR DIA >25 THEN BEEP :GOTO 4020
  377. 4030  AB=3.14159*(DIA/10)^2/4
  378. 4040  ASL=(CINT(AS*B))/100 :ASS=(CINT(AS*L))/100
  379. 4050  NBL=INT(ASL/AB)+1 :NBS=INT(ASS/AB)+1
  380. 4060  APL=(CINT(NBL*AB*100))/100
  381. 4070  APS=(CINT(NBS*AB*100))/100
  382. 4080  PRINT
  383. 4090  PRINT "  LONG  DIR :  As(req)="AS" X"B"/100 ="ASL" cm2"
  384. 4100  PRINT "      USE  [ "NBL;CHR$(237);DIA " mm  ]     As (prov.) ="APL" cm2 "
  385. 4110  PRINT
  386. 4120  PRINT "  SHORT DIR :  As(req)="AS" X"L"/100 ="ASS" cm2"
  387. 4130  PRINT "      USE  [ "NBS;CHR$(237);DIA " mm  ]     As (prov.) ="APS" cm2 "
  388. 4140  PRINT
  389. 4200  '---------------------------------------------------- PRINT DATA & RESULTS
  390. 4205  PRINT
  391. 4210  PRINT "     ***  DO YOU WHANT THIS COL. FOOTING DESIGN TO BE PRINTED  (Y/N) ?  ***";
  392. 4215  Y$=INKEY$ :IF Y$="" THEN 4215
  393. 4220  IF Y$="Y" OR Y$="y" THEN PRINT " YES" :GOTO 4230
  394. 4222  IF Y$="N" OR Y$="n" THEN PRINT " NO " :GOTO 4900
  395. 4225  GOTO 4210
  396. 4230  H$=STRING$(79,61)
  397. 4240  IF FY<=3000 THEN BRDA$=CHR$(239)+CHR$(8)+CHR$(47) ELSE BRDA$=CHR$(111)+CHR$(8)+CHR$(84)
  398. 4242  LPRINT
  399. 4245  LPRINT CHR$(14)"Arabian Consulting Engineering Services"
  400. 4250  LPRINT "P. O. Box  146                                           Riyadh - Saudi Arabia"
  401. 4255  LPRINT H$
  402. 4260  LPRINT CHR$(14)" PROJECT: "PRJ$
  403. 4265  LPRINT
  404. 4270  LPRINT "  BUILDING    : "BLD$ TAB(58)"PAGE No.:"
  405. 4275  LPRINT "  DESIGNED BY : "DSR$ TAB(31)"/ CHECKED BY : "TAB(58)"DATE    : "DATE$
  406. 4280  LPRINT :LPRINT H$
  407. 4285  LPRINT "  RCDESIGN PROGRAM PREPARED BY : Amjad J.El-Sha'ir, P.O.Box 926447 Amman-Jordan"
  408. 4290  LPRINT "  THIS COPY TO BE USED ONLY BY : Arabian Consulting Engineering Services  K.S.A"
  409. 4295  LPRINT H$
  410. 4300  LPRINT CHR$(14) " SINGLE COLUMN FOOTING "TAB(36) "F"NMB
  411. 4310  LPRINT H$
  412. 4320  LPRINT CHR$(27)"G";
  413. 4330  LPRINT "  ** SOIL CONDITIONS **  "
  414. 4340  LPRINT CHR$(27)"H";"  ---------------------  "
  415. 4350  LPRINT "   - Allowable Soil Bearing Capacity   q (all.) ="QA" kg/cm2  "
  416. 4360  LPRINT CHR$(27)"G"
  417. 4370  LPRINT "  ** CONCRETE & STEEL PROPERTIES **  "
  418. 4380  LPRINT CHR$(27)"H";"  ---------------------------------  "
  419. 4390  LPRINT "   - Concrete Crushing Strength  f'c ="FC" kg/cm2  "
  420. 4400  LPRINT "   - Reinf' Steel Yield Stress   fy  ="FY" kg/cm2  "
  421. 4410  LPRINT CHR$(27)"G"
  422. 4420  LPRINT "  ** COLUMN DIMENSIONS & LOADING **  "
  423. 4430  LPRINT CHR$(27)"H";"  ---------------------------------  "
  424. 4440  LPRINT "   - Column Dimentions     t x b = "TC" x"BC" cm"
  425. 4450  LPRINT "   - Ultimate Column  Load    Pu ="PU" ton "
  426. 4460  LPRINT CHR$(27)"G"
  427. 4470  LPRINT "  ** FOOTING  DIMENSIONS **  "
  428. 4480  LPRINT CHR$(27)"H";"  -------------------------  "
  429. 4490  LPRINT "   - Plain  Concrete  :   L' X B' X H' ="L+20" X"B+20" X 10  cm"
  430. 4500  LPRINT "   - Reinf' Concrete  :   L  X B  X H  ="L" X"B" X"H" cm"
  431. 4510  LPRINT H$
  432. 4520  LPRINT "  Min reinf' Steel Area  As(min)= .002 X H X 100 ="AS(MIN)" cm2 /one meter strip"
  433. 4530  LPRINT "  Max. Ultimate Shear Stress in Concrete     vuc ="VSC" kg/cm2"
  434. 4540  LPRINT "  Max. Ultimate Punch Stress in Concrete     vpc ="VPC" kg/cm2"
  435. 4550  LPRINT H$
  436. 4560  LPRINT CHR$(27)"G"
  437. 4570  LPRINT "  **  Check Pressure on Soil  ** "
  438. 4580  LPRINT CHR$(27)"H";"  ------------------------------ "
  439. 4590  LPRINT "     q ="LFCT"x Pu x 1000/(1.50 x L x B) ="Q" kg/cm2  < q (all)"
  440. 4600  LPRINT CHR$(27)"G"
  441. 4610  LPRINT "  **  Ult. Pressure on Footing  **"
  442. 4620  LPRINT CHR$(27)"H";"  --------------------------------"
  443. 4630  LPRINT "     q (ult)  =  Pu x 1000/(L x B)   ="QU" kg/cm2 "
  444. 4640  LPRINT CHR$(27)"G"
  445. 4650  LPRINT "  **  Check for Shear Stress  ** "
  446. 4660  LPRINT CHR$(27)"H";"  ------------------------------ "
  447. 4670  LPRINT "     Shear Stress at (d) from Col. face ="VS" kg/cm2  < vc "
  448. 4680  LPRINT CHR$(27)"G"
  449. 4690  LPRINT "  **  Check for Punching Shear Stress  ** "
  450. 4700  LPRINT CHR$(27)"H";"  --------------------------------------- "
  451. 4710  LPRINT "     Punching Shear Stress              ="VPS" kg/cm2  < vpc"
  452. 4720  LPRINT CHR$(27)"G"
  453. 4730  LPRINT "  **  FOOTING REINFORCEMENT  **  "
  454. 4740  LPRINT CHR$(27)"H";"  -----------------------------  "
  455. 4750  LPRINT "      Moment at Face of Wall  Mu ="MU1" t.m /one meter strip"
  456. 4760  IF AS1>=AS(MIN) GOTO 4790
  457. 4770  LPRINT "      Required Area of Steel  As ="AS1" cm2 /one meter strip  <  As (min.)"
  458. 4780  GOTO 4800
  459. 4790  LPRINT "      Required Area of Steel  As ="AS1" cm2 /one meter strip  >  As (min.)"
  460. 4800  LPRINT
  461. 4810  LPRINT "  LONG  DIR :  As(req)="AS" X"B" ="ASL" cm2"
  462. 4820  LPRINT CHR$(27)"G";
  463. 4830  LPRINT "             USE  [ "NBL;BRDA$;DIA " mm  ]     As (prov.) ="APL" cm2 "
  464. 4840  LPRINT CHR$(27)"H"
  465. 4850  LPRINT "  SHORT DIR :  As(req)="AS" X"L" ="ASS" cm2"
  466. 4860  LPRINT CHR$(27)"G";
  467. 4870  LPRINT "             USE  [ "NBS;BRDA$;DIA " mm  ]     As (prov.) ="APS" cm2 "
  468. 4880  LPRINT CHR$(27)"H";
  469. 4890  LPRINT CHR$(12)
  470. 4900  PRINT
  471. 4910  PRINT "     ***  DO YOU HAVE OTHER COL. FOOTINGS TO DESIGN            (Y/N) ?  ***";
  472. 4920  Y$=INKEY$ :IF Y$="" THEN 4920
  473. 4930  IF Y$="Y" OR Y$="y" THEN PRINT " YES" :GOTO 2580
  474. 4940  IF Y$="N" OR Y$="n" THEN PRINT " NO " :GOTO 110
  475. 4950  GOTO 4910
  476. 5000  END '-----------------------------------------------END OF FOOTINGS DESIGN
  477. 6000  '***********************    SUBROUTINES    *******************************
  478. 6100  '----------------------------------------- SUBROUTINE  for Invalid Entries
  479. 6110  PRINT :LOCATE ,6 :COLOR ,4 : BEEP
  480. 6120  PRINT "  ***   YOU WERE GIVEN TWO CHANCES TO ENTER BUT YOU FAILED   ***  "
  481. 6130  PRINT :COLOR ,4 :LOCATE ,6
  482. 6140  PRINT "  ***  ENTER  Y  TO START AGAIN OR TO GO FOR OTHER FOOTINGS  ***  "
  483. 6150  COLOR ,1 :PRINT
  484. 6160  RETURN
  485. 6200  '--------------------------------------------- SUBROUTINE  to display data
  486. 6210  CLS :LOCATE 2,12
  487. 6220  PRINT "  ****    CONCRETE WALL FOOTING     *    WF"NMB " ****"
  488. 6230  PRINT
  489. 6240  PRINT "         Allowable  Soil Bearing Capacity    q (all) ="QA" kg/cm2"
  490. 6250  PRINT
  491. 6260  PRINT "   MATERIAL PROPERTIES :    Conc. f'c ="FC"kg/cm2  *  Steel  fy ="FY"kg/cm2"
  492. 6270  PRINT
  493. 6280  RETURN
  494. 6300  '--------------------------------------------- SUBROUTINE  to display data
  495. 6310  CLS :LOCATE 2,12
  496. 6320  PRINT "  ****    SINGLE COLUMN FOOTING     *     F"NMB " ****"
  497. 6330  PRINT
  498. 6340  PRINT "         Allowable  Soil Bearing Capacity    q (all) ="QA" kg/cm2"
  499. 6350  PRINT
  500. 6360  PRINT "   MATERIAL PROPERTIES :    Conc. f'c ="FC"kg/cm2  *  Steel  fy ="FY"kg/cm2"
  501. 6370  PRINT
  502. 6380  RETURN
  503. 6400  '------------------- SUBROUTINE to find the requierd  AREA OF STEEL REINF'
  504. 6410  WC=(1-SQR(1-2.36*MU/(100*D^2*0.9*FC)))/1.18
  505. 6420  AC=(WC/0.85)*D       'depth of compression Whitny Block
  506. 6430  CC=AC/0.85           'depth of nutral axis
  507. 6440  PS=WC*FC/FY              'steel ratio
  508. 6450  AS=PS*100*D              'area of steel reinf'
  509. 6460  RETURN
  510. 6500  '------------------------------------- SUBROUTINE to Check  Punching Shear
  511. 6510  VPC=SQR(FC)
  512. 6520  BO=2*(TC+D+BC+D)              'Punching Parameter  m
  513. 6530  VP=PU*1000-QU*(TC+D)*(BC+D)   'Punching Force      kg
  514. 6540  VPS=VP/(0.85*BO*D)             'Punching Stress     kg/cm2
  515. 6550  IF VPS<VPC GOTO 6570
  516. 6560  D=D+5 :GOTO 6520
  517. 6570  VPC=(CINT(VPC*100))/100
  518. 6580  VPS=(CINT(VPS*100))/100
  519. 6590  RETURN
  520.